AddEqualSetback Method

Description

Creates one or more Chamfer objects from an array of edge sets.

Syntax

Visual Basic
Public Function AddEqualSetback( _ ByVal NumberOfEdgeSets As Long, _ ByVal EdgeSetArray As Variant, _ ByVal SetbackDistance As Double _ ) As Chamfer

Parameters

NumberOfEdgeSets: Specifies the number of edges on which to place Chamfer objects.
EdgeSetArray: Specifies the intersecting edges that are to be replaced with a Chamfer object.
SetbackDistance: Specifies the distance of the setbacks. This value must be greater than zero.

Remarks

An edge set consists of two intersecting edges. To use this method, the two intersecting edges of each edge set must form a 90-degree angle. The result of the AddEqualSetback method is a chamfer at the intersection of each set of edges, with equal length setbacks angled at 45 degrees. The setback distance is measured along the faces from the intersection of the edges. The setbacks determine the chamfer start and stop locations. All edge set intersections in the array will have the same setback distance.

Example

Example (Visual Basic)

Private Sub Form_Load()
    Dim objApp As SolidEdgeFramework.Application
    Dim objDoc As SolidEdgePart.PartDocument
    Dim objProfArr(1 To 2) As SolidEdgePart.Profile
    Dim objModel As SolidEdgePart.Model
    Dim objChmfr As SolidEdgePart.Chamfer
    Dim objLines As SolidEdgeFrameworkSupport.Lines2d
    Dim objRelns1 As SolidEdgeFrameworkSupport.Relations2d
    Dim objExtProt As SolidEdgePart.ExtrudedProtrusion
    Dim objEdgs As Object
    Dim objEdgArr(1 To 4) As Object
    Dim lngStatus As Long
    'Report errors
    Const PI = 3.14159265358979
    'Create/get the application with specific settings
    On Error Resume Next
    Set objApp = GetObject(, "SolidEdge.Application")
    If Err Then
        Err.Clear
        Set objApp = CreateObject("SolidEdge.Application")
        Set objDoc = objApp.Documents.Add("SolidEdge.PartDocument")
        objApp.Visible = True
    Else
        Set objDoc = objApp.ActiveDocument
    End If
    ' Draw the Profile
    Set objProfArr(1) = objDoc.ProfileSets.Add.Profiles.Add(pRefPlaneDisp:=objDoc.RefPlanes(1))
    Set objLines = objProfArr(1).Lines2d
    Call objLines.AddBy2Points(x1:=0, y1:=0, x2:=0.06, y2:=0)
    Call objLines.AddBy2Points(x1:=0.06, y1:=0, x2:=0.06, y2:=0.06)
    Call objLines.AddBy2Points(x1:=0.06, y1:=0.06, x2:=0, y2:=0.06)
    Call objLines.AddBy2Points(x1:=0, y1:=0.06, x2:=0, y2:=0)
    ' Relate the Lines to make the Profile closed
    Set objRelns1 = objProfArr(1).Relations2d
    Call objRelns1.AddKeypoint(Object1:=objLines(1), Index1:=igLineEnd, Object2:=objLines(2), Index2:=igLineStart)
    Call objRelns1.AddKeypoint(Object1:=objLines(2), Index1:=igLineEnd, Object2:=objLines(3), Index2:=igLineStart)
    Call objRelns1.AddKeypoint(Object1:=objLines(3), Index1:=igLineEnd, Object2:=objLines(4), Index2:=igLineStart)
    Call objRelns1.AddKeypoint(Object1:=objLines(4), Index1:=igLineEnd, Object2:=objLines(1), Index2:=igLineStart)
    ' Check for the Profile Validity
    lngStatus = objProfArr(1).End(ValidationCriteria:=igProfileClosed)
    If lngStatus <> 0 Then
        MsgBox ("Profile not closed")
    End If
    ' Create the Base Protrusion Object
    Set objModel = objDoc.Models.AddFiniteExtrudedProtrusion(NumberOfProfiles:=1, _
                                                             ProfileArray:=objProfArr, profileplaneSide:=igRight, _
                                                             ExtrusionDistance:=0.02)
    objProfArr(1).Visible = False
    ' Check the status of Base Feature
    If objModel.ExtrudedProtrusions(1).Status <> igFeatureOK Then
        MsgBox ("Error in the Creation of Base Protrusion Feature object")
    End If
    Set objExtProt = objModel.ExtrudedProtrusions(1)
    ' Get the Edges collection
    Set objEdgs = objExtProt.Edges(EdgeType:=igQueryAll)
    ' Get the Edges and store them in an Array
    Set objEdgArr(1) = objEdgs(5)
    Set objEdgArr(2) = objEdgs(8)
    ' Create a Chamfer object
    Set objChmfr = objModel.Chamfers.AddEqualSetback(NumberOfEdgeSets:=2, _
                                                     EdgeSetArray:=objEdgArr, SetbackDistance:=0.005)
    ' USER DISPLAY
    'Release objects
    Set objApp = Nothing
    Set objDoc = Nothing
    Set objProfArr(1) = Nothing
    Set objModel = Nothing
    Set objExtProt = Nothing
    Set objLines = Nothing
    Set objRelns1 = Nothing
    Set objChmfr = Nothing
    Set objEdgs = Nothing
    Set objEdgArr(1) = Nothing
    Set objEdgArr(2) = Nothing
End Sub